一次元配列を昇順並び替え(ソート)する【クイックソート】【ExcelVBA】

パーツ化とは
このコードをコピペでOK
1. 使い方
注意点
関連記事

パーツ化とは

ExcelVBAマクロ初級者からの脱却が、処理のパーツ化(プロシージャの分割)と考えています。
マクロを作る上で基本機能をパーツ化する事で、開発時間の削減に繋がります。
処理はパーツ単位で分ける事を心掛けましょう。

分かりやすく説明すると、エクセルの「関数」と同様です。
SUM関数であればセル内に「=SUM(1+2+3)」と記載すれば、セルには「6」と表示されますよね。
値を渡せば正しい値で返ってくる動きです。

このコードをコピペでOK

'■一次元配列をソートする(クイックソート)
Public Function Call_QuicksSort(ByRef arr As Variant, ByVal sStart As Long, ByVal sEnd As Long)
    Dim sLeft  As Long: sLeft = sStart
    Dim sRight As Long: sRight = sEnd
    Dim sMid As Variant
    Dim temp As Variant
    
    '■配列の中央値を取得
    sMid = arr(Int((sStart + sEnd) / 2))
    
    Do
        '■①先頭から中央値をループし、中央値より大きい値を探す
        Do
            If (arr(sLeft) >= sMid) Then Exit Do
            sLeft = sLeft + 1
        Loop
        
        '■②中央値から最終をループ、中央値より大きい値を探す
        Do
            If (sMid >= arr(sRight)) Then Exit Do
            sRight = sRight - 1
        Loop
        
        '■①＞＝②になれば処理終了
        If (sLeft >= sRight) Then Exit Do
        
        '■①＜②であれば再度入替
        temp = arr(sLeft)
        arr(sLeft) = arr(sRight)
        arr(sRight) = temp
        
        sLeft = sLeft + 1
        sRight = sRight - 1
    Loop
    
    '■中央値から先頭側を再帰処理
    If (sStart < sLeft - 1) Then Call Call_QuicksSort(arr, sStart, sLeft - 1)
    
    '■中央値から最終側を再帰処理
    If (sRight + 1 < sEnd) Then Call Call_QuicksSort(arr, sRight + 1, sEnd)
    
End Function

使い方

上記をコピペでお好きなモジュール内に記載してください。

Public Sub test()

    Dim arr As Variant
    arr = Array(8, 5, 1, 2, 9, 4, 3, 6, 7)
    
    Call Call_QuicksSort(arr, LBound(arr), UBound(arr))
          
    '■配列が以下のようにソートされる
    '0 1 2 3 4 5 6 7 8 9
End Sub