VBA開発

ExcelVBAマクロ「CSVファイルを文字列形式で開く」をパーツ化する

パーツ化とは

ExcelVBAマクロ初級者からの脱却が、処理のパーツ化(プロシージャの分割)と考えています。
マクロを作る上で基本機能をパーツ化する事で、開発時間の削減に繋がります。

分かりやすく説明すると、エクセルの「関数」と同様です。
SUM関数であれば セル内に「=SUM(1+2+3)」と記載すれば、セルには「6」と表示されますよね。
値を渡せば正しい値で返ってくる動きです。

このコードをコピペでOK

'■CSVを開く(文字列書式指定)
Public Function Call_CsvStringOpen() As Boolean
    Const MAX_COL As Long = 16384   'Excel2003までは256にします※256以上はエラー
    Dim FileName As String, NewName As String
    Dim StringPaste(MAX_COL - 1) As Variant
    Dim i As Long
    
    '■ファイル名入力
    FileName = Application.GetOpenFilename("CSVファイル,*.txt;*.csv")
    If FileName = "False" Then
        Call_CsvStringOpen = False
        Exit Function
    End If
    
    '■拡張子「.csv」の場合は「.txt」に変更する
    If Right(FileName , 4) = ".csv" Then
        NewName = Left(FileName , Len(FileName ) - 4) + ".txt"
        FileCopy FileName , NewName
        'Kill FileName      '拡張子CSVのファイルを削除してtxtファイルのみ残す場合はコメントを外す。
        FileName = NewName
    End If
    
    '■全ての列の書式を文字列にする
    For i = 1 To MAX_COL
        StringPaste(i - 1) = Array(i, 2)
    Next
    
    '■ファイルOpen
    Workbooks.OpenText Filename:=FileName , StartRow:=1, DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, Semicolon:=False, _
        Comma:=True, Space:=False, Other:=False, FieldInfo:=StringPaste
    
    Call_CsvStringOpen = True
End Function

使い方

上記をコピペでお好きなモジュール内に記載してください。

     '■以下コード実行後、CSVファイルを選べば文字列で開いた状態で開く(Trueが戻る)
     '■                選んでなければ何も変わらない(Falseが戻る)
     MsgBox Call_CsvStringOpen

注意点

  • ダブルクォーテーション(”)で括られている、CSVファイルは開けません。
  • TAB区切りのテキストファイルは開けません。(カンマ区切りのテキストファイルはOK)
    →TAB区切りテキストを文字列形式で開く場合はこちらの記事を参照。

どんな時に使える?

  • ネットショップからの売上データをダウンロードして、発注書を作成する。
    →型番などのデータでJANコードが指数表示になるとNG。
    その為、文字列形式で開きます。
  • POSレジシステムから出力された顧客CSVファイルをマクロで読込、DM用差し込み印刷データを作成する
    →電話番号データの先頭0が欠落してしまうとNG。
    その為、文字列形式で開きます。
単純に変換するだけであれば下記のフリーソフトもおすすめです。
CSV to Excel

コメント

タイトルとURLをコピーしました